
Installation
The package can be installed by adding oidcc_plug to your list of dependencies
in mix.exs:
def deps do
  [
    {:oidcc_plug, "~> 0.5.1"}
  ]
end
You can use igniter to generate a basic
setup for phoenix:
# If you haven't created your phoenix project yet
# See: https://hexdocs.pm/igniter/readme.html#creating-a-new-mix-project-using-igniter
mix igniter.new test \
  --install phoenix,oidcc,oidcc_plug \
  --with phx.new

# Add Igniter Phoenix Extension
mix igniter.add_extension phoenix

# Generate Provider, Controller, Router & Config
mix oidcc_plug.gen.controller \
    --name MyAppWeb.AuthController \
    --provider MyApp.OpenIDProvider \
    --base-url /auth \
    --issuer https://account.google.com \
    --client-id client-id

Usage
Setup
defmodule SampleApp.Application do
  # ...

  @impl Application
  def start(_type, _args) do
    children = [
      # ...

      {Oidcc.ProviderConfiguration.Worker, %{
        issuer: "https://accounts.google.com",
        name: SampleApp.GoogleOpenIdConfigurationProvider
      }},

      # Start the Endpoint (http/https)
      SampleAppWeb.Endpoint
    ]

    # See https://hexdocs.pm/elixir/Supervisor.html
    # for other strategies and supported options
    opts = [strategy: :one_for_one, name: SampleApp.Supervisor]
    Supervisor.start_link(children, opts)
  end

  # ...
end
Authorization Flow
defmodule SampleAppWeb.OidccController do
  use SampleAppWeb, :controller

  plug Oidcc.Plug.Authorize,
    [
      provider: TestWorks.OpenIdConfigurationProvider,
      client_id: "client_id",
      client_secret: "client_secret",
      redirect_uri: &__MODULE__.callback_uri/0
    ]
    when action in [:authorize]

  plug Oidcc.Plug.AuthorizationCallback,
    [
      provider: TestWorks.OpenIdConfigurationProvider,
      client_id: "client_id",
      client_secret: "client_secret",
      redirect_uri: &__MODULE__.callback_uri/0
    ]
    when action in [:callback]

  @doc false
  def callback_uri, do: url(~p"/oidcc/callback")

  def authorize(conn, _params), do: conn

  def callback(%Plug.Conn{private: %{
    Oidcc.Plug.AuthorizationCallback => {:ok, {_token, userinfo}}}
  } = conn, params) do
    conn
    |> put_session("oidcc_claims", userinfo)
    |> redirect(to: "/")
  end

  def callback(%Plug.Conn{private: %{
    Oidcc.Plug.AuthorizationCallback => {:error, reason}
  }} = conn, _params) do
    conn
    |> put_status(400)
    |> render(:error, reason: reason)
  end
end
API (Check access token header)
defmodule SampleAppWeb.Endpoint do
  use Phoenix.Endpoint, otp_app: :sample_app

  # ...

  plug Oidcc.Plug.ExtractAuthorization

  @client_id Application.compile_env!(:sample_app, [:openid_credentials, :client_id])
  @client_secret Application.compile_env!(:sample_app, [:openid_credentials, :client_secret])

  # Ensure Authorization Token provided
  plug Oidcc.Plug.RequireAuthorization

  # Check Token via Introspection
  plug Oidcc.Plug.IntrospectToken,
    provider: SampleApp.GoogleOpenIdConfigurationProvider,
    client_id: @client_id,
    client_secret: @client_secret

  # OR: Check Token via Userinfo
  plug Oidcc.Plug.LoadUserinfo,
    provider: SampleApp.GoogleOpenIdConfigurationProvider,
    client_id: @client_id,
    client_secret: @client_secret

  # OR: Check Token via JWT validation
  plug Oidcc.Plug.ValidateJwtToken,
    provider: SampleApp.GoogleOpenIdConfigurationProvider,
    client_id: @client_id,
    client_secret: @client_secret

  plug SampleAppWeb.Router
end

Retrieve Token for Code Flow Authorization Callback
This plug does not send a response. Instead it will load and validate all
token data and leave the rest to a controller action that will be executed
after.
Via Phoenix.Router
defmodule SampleAppWeb.Router do
  use Phoenix.Router

  # ...

  pipeline :oidcc_callback do
    plug Oidcc.Plug.AuthorizationCallback,
      provider: SampleApp.GoogleOpenIdConfigurationProvider,
      client_id: Application.compile_env!(:sample_app, [Oidcc.Plug.Authorize, :client_id]),
      client_secret: Application.compile_env!(:sample_app, [Oidcc.Plug.Authorize, :client_secret]),
      redirect_uri: "https://localhost:4000/oidcc/callback"
  end

  forward "/oidcc/authorize", to: Oidcc.Plug.Authorize,
    init_opts: [...]

  scope "/oidcc/callback", SampleAppWeb do
    pipe_through :oidcc_callback

    get "/", AuthController, :handle_callback
    post "/", AuthController, :handle_callback
  end
end
Via Controller
defmodule SampleAppWeb.AuthController do
  # ...

  plug Oidcc.Plug.AuthorizationCallback,
    provider: SampleApp.GoogleOpenIdConfigurationProvider,
    client_id: Application.compile_env!(:sample_app, [Oidcc.Plug.Authorize, :client_id]),
    client_secret: Application.compile_env!(:sample_app, [Oidcc.Plug.Authorize, :client_secret]),
    redirect_uri: "https://localhost:4000/oidcc/callback"
    when action in [:handle_callback]

  def handle_callback(
    %Plug.Conn{private: %{
      Oidcc.Plug.AuthorizationCallback => {:ok, {token, userinfo}}
      Oidcc.Plug.Authorize.State => "query_param_state" | nil
    }},
    _params
  ) do
    # Handle Success

    conn
    |> put_session("auth_token", token)
    |> put_session("auth_userinfo", userinfo)
    |> redirect(to: "/")
  end

  def handle_callback(
    %Plug.Conn{private: %{
      Oidcc.Plug.AuthorizationCallback => {:error, reason}}
    },
    _params
  ) do
    # Handle Error

    conn
    |> put_status(400)
    |> render("error.html", reason: reason)
  end
end

          @type error() ::
  :oidcc_client_context.error()
  | :oidcc_token.error()
  | :oidcc_userinfo.error()
  | :useragent_mismatch
  | :peer_ip_mismatch
  | :missing_authorize_session
  | :state_not_verified
  | {:missing_request_param, param :: String.t()}

          @type opts() :: [
  provider: GenServer.name() | nil,
  client_store: module() | nil,
  client_id: String.t() | (-> String.t()) | (Plug.Conn.t() -> String.t()) | nil,
  client_secret:
    String.t() | (-> String.t()) | (Plug.Conn.t() -> String.t()) | nil,
  client_context_opts:
    :oidcc_client_context.opts() | (-> :oidcc_client_context.opts()),
  client_profile_opts: :oidcc_profile.opts(),
  redirect_uri: String.t() | (-> String.t()) | (Plug.Conn.t() -> String.t()),
  check_useragent: boolean(),
  check_peer_ip: boolean(),
  retrieve_userinfo: boolean(),
  request_opts: :oidcc_http_util.request_opts()
]


      


Plug Configuration Options
Options
	provider - name of the Oidcc.ProviderConfiguration.Worker
	client_id - OAuth Client ID to use for the introspection
	client_secret - OAuth Client Secret to use for the introspection
	client_context_opts - Options for Client Context Initialization
	client_profile_opts - Options for Client Context Profiles
	redirect_uri - Where to redirect for callback
	check_useragent - check if useragent is the same as before the
authorization request
	check_peer_ip - check if the client IP is the same as before the
authorization request
	retrieve_userinfo - whether to load userinfo from the provider
	request_opts - request opts for http calls to provider
	client_store - A module name that implements the Oidcc.Plug.ClientStore behaviour
to fetch the client context from a store instead of using the provider, client_id and client_secret
directly. This is useful for storing the client context in a database or other persistent
storage.

Initiate Code Flow Authorization Redirect
defmodule SampleAppWeb.Router do
  use Phoenix.Router

  # ...

  forward "/oidcc/authorize", to: Oidcc.Plug.Authorize,
    init_opts: [
      provider: SampleApp.GoogleOpenIdConfigurationProvider,
      client_id: Application.compile_env!(:sample_app, [Oidcc.Plug.Authorize, :client_id]),
      client_secret: Application.compile_env!(:sample_app, [Oidcc.Plug.Authorize, :client_secret]),
      redirect_uri: "https://localhost:4000/oidcc/callback"
    ]
end
Query Params
	state - State to relay to OpenID Provider. Commonly used for target redirect
URL after authorization.
Accessible through Plug.Conn.private[Elixir.Oidcc.Plug.Authorize.State] after Oidcc.Plug.AuthorizationCallback

Redirect Modes
The plug has two redirect modes.
In :inline mode, the plug automatically sends a redirect response.
In :manual mode, the plug assigns the redirect URI as a private value to the
connection. You will need to perform the redirect in your controller function.
plug Oidcc.Plug.Authorize,
     [
       # ...
       redirect_mode: :manual
     ]
     when action == :request

def request(conn, params) do
  redirect_uri = Map.fetch!(conn.private, Oidcc.Plug.Authorize)

  conn
  |> put_resp_header("location", redirect_uri)
  |> send_resp(302, "")
end
This mode is useful if you need to put values into the session before the
redirect, or if you need to create a continuity cookie for an OIDC provider
that uses the form_post response type.

          @type opts() :: [
  scopes: :oidcc_scope.scopes(),
  redirect_uri: String.t() | (-> String.t()) | (Plug.Conn.t() -> String.t()),
  redirect_mode: :inline | :manual,
  url_extension: :oidcc_http_util.query_params(),
  provider: GenServer.name() | nil,
  client_store: module() | nil,
  client_id: String.t() | (-> String.t()) | (Plug.Conn.t() -> String.t()) | nil,
  client_secret:
    String.t() | (-> String.t()) | (Plug.Conn.t() -> String.t()) | nil,
  client_context_opts:
    :oidcc_client_context.opts() | (-> :oidcc_client_context.opts()) | nil,
  client_profile_opts: :oidcc_profile.opts(),
  purpose: String.t(),
  require_purpose: boolean(),
  require_pkce: boolean(),
  response_mode: String.t(),
  request_opts: :oidcc_http_util.request_opts()
]


      


Plug Configuration Options
Options
	scopes - scopes to request
	redirect_uri - Where to redirect for callback
	redirect_mode - Selects how the redirect happens. Either :inline or :manual.
	url_extension - Custom query parameters to add to the redirect URI
	provider - name of the Oidcc.ProviderConfiguration.Worker
	client_id - OAuth Client ID to use for the introspection
	client_secret - OAuth Client Secret to use for the introspection
	client_context_opts - Options for Client Context Initialization
	client_profile_opts - Options for Client Context Profiles
	client_store - A module name that implements the Oidcc.Plug.ClientStore behaviour
to fetch the client context from a store instead of using the provider, client_id and client_secret
directly. This is useful for storing the client context in a database or other persistent
storage.
	purpose - purpose of the authorization request, see [https://cdn.connectid.com.au/specifications/oauth2-purpose-01.html]
	require_purpose - whether to require a purpose value
	require_pkce - whether to require PKCE when getting the token
	response_mode - response mode to use (defaults to "query")
	request_opts - config for the pushed authorization HTTP request

Behaviour to cache introspection / userinfo requests
Usage
	Userinfo: See Oidcc.Plug.LoadUserinfo.opts/0 / cache
	Introspection: See Oidcc.Plug.IntrospectToken.opts/0 / cache

        Check cache if userinfo / introspection is stored for token.



    


    
      
        put(type, token, data, conn)

      


        Store userinfo / introspection for token.

          @callback get(type :: :userinfo, token :: String.t(), conn :: Plug.Conn.t()) ::
  {:ok, :oidcc_jwt_util.claims()} | :miss


          @callback get(type :: :introspection, token :: String.t(), conn :: Plug.Conn.t()) ::
  {:ok, Oidcc.TokenIntrospection.t()} | :miss


      


Check cache if userinfo / introspection is stored for token.

          @callback put(
  type :: :userinfo,
  token :: String.t(),
  data :: :oidcc_jwt_util.claims(),
  conn :: Plug.Conn.t()
) :: :ok


          @callback put(
  type :: :introspection,
  token :: String.t(),
  data :: Oidcc.TokenIntrospection.t(),
  conn :: Plug.Conn.t()
) :: :ok


      


Store userinfo / introspection for token.

Behaviour for retrieving and managing OpenID Connect client contexts.
This module defines the callbacks that must be implemented by any client store
used with the Oidcc.Plug components. A client store is responsible for:
	Retrieving the client context from a connection
	Optionally refreshing the JSON Web Key Set (JWKS) for a client context

Examples
defmodule MyApp.OktaClientStore do
  @behaviour Oidcc.Plug.ClientStore

  alias Oidcc.ClientContext
  alias Oidcc.ProviderConfiguration

  @impl Oidcc.Plug.ClientStore
  def get_client_context(conn) do
    with email when is_binary(email) <- conn.assigns[:email],
      {:ok, okta_config} <- get_okta_oidc_config(email),
      {:ok,
        {
          %ProviderConfiguration{} = configuration,
          _expiry
        }} <- ProviderConfiguration.load_configuration(okta_config.issuer),
      {:ok, {jwks, _expiry}} <- ProviderConfiguration.load_jwks(configuration.jwks_uri),
      %ClientContext{} = client_context <-
        ClientContext.from_manual(configuration, jwks, okta_config.client_id, okta_config.client_secret) do
      {:ok, client_context}
    end
  end

  defp get_okta_oidc_config(email) do
    # Implementation depends on your application's needs
    # This is just a placeholder
    {:ok, %{issuer: "https://my-domain.okta.com", client_id: "my_client_id", client_secret: "my_client_secret"}}
  end
end

          @callback get_client_context(conn :: Plug.Conn.t()) ::
  {:error, term()} | {:ok, Oidcc.ClientContext.t()}

        (optional)


        
          
        

    

  


  

      

          @callback refresh_jwks(context :: Oidcc.ClientContext.t()) ::
  {:ok, JOSE.JWK.t()} | {:error, term()}

Extract authorization request header
This module should be used together with Oidcc.Plug.IntrospectToken,
Oidcc.Plug.LoadUserinfo or Oidcc.Plug.ValidateJwtToken.
defmodule SampleAppWeb.Endpoint do
  use Phoenix.Endpoint, otp_app: :sample_app

  # ...

  plug Oidcc.Plug.ExtractAuthorization

  plug Oidcc.Plug.RequireAuthorization, [...] # Ensure Authorization Token provided
  plug Oidcc.Plug.IntrospectToken, [...] # Check Token via Introspection
  plug Oidcc.Plug.LoadUserinfo, [...] # Check Token via Userinfo
  plug Oidcc.Plug.ValidateJwtToken, [...] # Check Token via JWT validation

  plug SampleAppWeb.Router
end

          @type opts() :: [
  {:send_invalid_header_response,
   (conn :: Plug.Conn.t(), given_header :: [String.t()] -> Plug.Conn.t())}
]


      


Plug Configuration Options
Options
	send_invalid_header_response - Customize Error Response for invalid header

Validate extracted authorization token using introspection.
See: https://datatracker.ietf.org/doc/html/rfc7662
This module should be used together with Oidcc.Plug.ExtractAuthorization.
This plug will send an introspection request for every request. To avoid this,
provide a cache to opts/0.
defmodule SampleAppWeb.Endpoint do
  use Phoenix.Endpoint, otp_app: :sample_app

  # ...

  plug Oidcc.Plug.ExtractAuthorization

  plug Oidcc.Plug.IntrospectToken,
    provider: SampleApp.GoogleOpenIdConfigurationProvider,
    client_id: Application.compile_env!(:sample_app, [Oidcc.Plug.IntrospectToken, :client_id]),
    client_secret: Application.compile_env!(:sample_app, [Oidcc.Plug.IntrospectToken, :client_secret])

  plug SampleAppWeb.Router
end

      


      
        Summary


  
    Types
  


    
      
        opts()

      


        Plug Configuration Options



    





      


      
        Types


        


  
    
      
    
    
      opts()


        (since 0.1.0)


        
          
        

    

  


  

      

          @type opts() :: [
  provider: GenServer.name(),
  client_id: String.t() | (-> String.t()) | (Plug.Conn.t() -> String.t()),
  client_secret: String.t() | (-> String.t()) | (Plug.Conn.t() -> String.t()),
  token_introspection_opts: :oidcc_token_introspection.opts(),
  send_inactive_token_response: (conn :: Plug.Conn.t(),
                                 introspection :: Oidcc.TokenIntrospection.t() ->
                                   Plug.Conn.t()),
  cache: Oidcc.Plug.Cache.t()
]


      


Plug Configuration Options
Options
	provider - name of the Oidcc.ProviderConfiguration.Worker
	client_id - OAuth Client ID to use for the introspection
	client_secret - OAuth Client Secret to use for the introspection
	token_introspection_opts - Options to pass to the introspection
	send_inactive_token_response - Customize Error Response for inactive token
	cache - Cache token introspection - See Oidcc.Plug.Cache
	client_store - A module name that implements the Oidcc.Plug.ClientStore behaviour
to fetch the client context from a store instead of using the provider, client_id and client_secret
directly. This is useful for storing the client context in a database or other persistent
storage.


  


        

      


  

    
Oidcc.Plug.LoadUserinfo 
    



      
Validate extracted authorization token using userinfo retrieval.
See: https://openid.net/specs/openid-connect-core-1_0.html#UserInfo
This module should be used together with Oidcc.Plug.ExtractAuthorization.
This plug will send a userinfo request for every request. To avoid this,
provide a cache to opts/0.
defmodule SampleAppWeb.Endpoint do
  use Phoenix.Endpoint, otp_app: :sample_app

  # ...

  plug Oidcc.Plug.ExtractAuthorization

  plug Oidcc.Plug.LoadUserinfo,
    provider: SampleApp.GoogleOpenIdConfigurationProvider,
    client_id: Application.compile_env!(:sample_app, [Oidcc.Plug.LoadUserinfo, :client_id]),
    client_secret: Application.compile_env!(:sample_app, [Oidcc.Plug.LoadUserinfo, :client_secret])

  plug SampleAppWeb.Router
end

          @type opts() :: [
  provider: GenServer.name(),
  client_id: String.t() | (-> String.t()) | (Plug.Conn.t() -> String.t()),
  client_secret: String.t() | (-> String.t()) | (Plug.Conn.t() -> String.t()),
  userinfo_retrieve_opts: :oidcc_userinfo.retrieve_opts(),
  send_inactive_token_response: (conn :: Plug.Conn.t() -> Plug.Conn.t()),
  cache: Oidcc.Plug.Cache.t()
]


      


Plug Configuration Options
Options
	provider - name of the Oidcc.ProviderConfiguration.Worker
	client_id - OAuth Client ID to use for the userinfo retrieval
	client_secret - OAuth Client Secret to use for the userinfo retrieval
	userinfo_retrieve_opts - Options to pass to userinfo loading
	send_inactive_token_response - Customize Error Response for inactive token
	cache - Cache userinfo response - See Oidcc.Plug.Cache

Ensure authorization token provided.
This module should be used together with Oidcc.Plug.ExtractAuthorization.
defmodule SampleAppWeb.Endpoint do
  use Phoenix.Endpoint, otp_app: :sample_app

  # ...

  plug Oidcc.Plug.ExtractAuthorization

  plug Oidcc.Plug.RequireAuthorization

  # Check Token with `Oidcc.Plug.IntrospectToken`, `Oidcc.Plug.LoadUserinfo` or `Oidcc.Plug.ValidateJwtToken`

  plug SampleAppWeb.Router
end

          @type opts() :: [
  {:send_missing_token_response, (conn :: Plug.Conn.t() -> Plug.Conn.t())}
]


      


Plug Configuration Options
Options
	send_missing_token_response - Customize Error Response for missing token

Validate extracted authorization token by validating it as a JWT token.
This module should be used together with Oidcc.Plug.ExtractAuthorization.
defmodule SampleAppWeb.Endpoint do
  use Phoenix.Endpoint, otp_app: :sample_app

  # ...

  plug Oidcc.Plug.ExtractAuthorization

  plug Oidcc.Plug.ValidateJwtToken,
    provider: SampleApp.GoogleOpenIdConfigurationProvider,
    client_id: Application.compile_env!(:sample_app, [Oidcc.Plug.ValidateJwtToken, :client_id]),
    client_secret: Application.compile_env!(:sample_app, [Oidcc.Plug.ValidateJwtToken, :client_secret]),
    # optional validation options to pass to Oidcc.Token.validate_id_token/3
    validate_opts: %{validate_azp: :any}

  plug SampleAppWeb.Router
end

          @type opts() :: [
  provider: GenServer.name(),
  client_id: String.t() | (-> String.t()),
  client_secret: String.t() | (-> String.t()),
  send_inactive_token_response: (conn :: Plug.Conn.t() -> Plug.Conn.t()),
  validate_opts: Oidcc.Token.retrieve_opts()
]


      


Plug Configuration Options
Options
	provider - name of the Oidcc.ProviderConfiguration.Worker
	client_id - OAuth Client ID to use for the token validation
	client_secret - OAuth Client Secret to use for the token validation
	send_inactive_token_response - Customize Error Response for inactive token
	client_store - A module name that implements the Oidcc.Plug.ClientStore behaviour
to fetch the client context from a store instead of using the provider, client_id and client_secret
directly. This is useful for storing the client context in a database or other persistent
storage.
	validate_opts - A map of options to pass to Oidcc.Token.validate_id_token/3.


  


        

      


  

    
Oidcc.Plug.Authorize.Error exception
    



      
Redirect URI Generation Failed
Check the reason field for ther exact reason

      




  

    
Oidcc.Plug.IntrospectToken.Error exception
    



      
Introspection Failed
Check the reason field for ther exact reason

      




  

    
Oidcc.Plug.LoadUserinfo.Error exception
    



      
Retrieve Userinfo Failed
Check the reason field for ther exact reason

      




  

    
Oidcc.Plug.ValidateJwtToken.Error exception
    



      
Validation Failed
Check the reason field for ther exact reason

      




  

    
mix oidcc_plug.gen.controller 
    



      
Generate an auth controller for your OpenID provider
Generates an auth controller that starts the OpenID Connect flow and handles
the result. Additionally, it will add the routes to your router.
Example
mix oidcc_plug.gen.controller \
  --name MyAppWeb.AuthController \
  --provider MyApp.OpenIDProvider \
  --base-url /auth \
  --issuer https://account.google.com \
  --client-id client-id

Options
	--name or -n - Name of the controller
	--provider or -p - Name of the OpenID Provider
	--base-url or -b - Base URL for the controller
	--issuer or -i - Issuer URL of the OpenID Provider
	--client-id - Client ID for the OpenID Provider
	--client-secret - Client Secret for the OpenID Provider

